
Draws a skeleton of exactly what is about to load.
Your own component renders from sample data with its text transparent; the browser lays it
out for real; rounded bars are drawn over it — one per wrapped line of text, one block per
image or control — in a shadow root. Nothing is guessed, so nothing moves when the content
arrives. A port of Skullet to Phoenix LiveView.
Live demo — every option on one page, running the
example app in this repo.
Installation
def deps do
  [
    {:skullet, "~> 0.1.0"}
  ]
end
Two lines of wiring, in assets/js/app.js and assets/css/app.css:
import { SkulletHook } from "../../deps/skullet/priv/static/skullet.js"

let liveSocket = new LiveSocket("/live", Socket, { hooks: { Skullet: SkulletHook } })
@import "../../deps/skullet/priv/static/skullet.css";
With a path: or git: dependency there is no deps/skullet directory — point the two
imports at that checkout instead. The CSS file is not optional: it is what keeps the sample
invisible before the engine runs.
priv/static ships two bundles, their pre-paint script and the stylesheet; only the first
two are yours to import:
	file	what it is
	skullet.js	the engine as one ES module — what a bundler imports
	skullet.min.js	the same engine as a script, with its source map: it defines window.Skullet (attach, setDebug, registerReveal, SkulletHook)
	skullet.pre.js	the pre-paint script Skullet.Boot inlines into the page, not a file you load
	skullet.css	the stylesheet

No build step? Copy skullet.min.js and skullet.css where your static files live and use
the engine off window.Skullet:
<link rel="stylesheet" href="/assets/skullet.css">
<script src="/assets/skullet.min.js"></script>
<script>
  Skullet.attach(document.querySelector(".skullet"))
</script>
The first skeleton
<Skullet.skeleton :let={user} id="profile" async={@user} sample={@sample_user}>
  <Profile.card user={user} />
</Skullet.skeleton>
While @user is loading, Profile.card is rendered from @sample_user and measured; when
the assign resolves, the skeleton reveals the real card in its place. sample is required
because it is the only data a dead render has, and id because the hook needs one and a
generated one would change every render.
Render <Skullet.Boot.boot /> once in the layout and that first skeleton is drawn before
the browser paints it, rather than after the bundle loads.
Under a Content Security Policy, Skullet wants a nonce in two places, and neither of them
is 'unsafe-inline':
	script-src for the boot script above, which is inlined;
	style-src for the theme, which is emitted as a <style> block rather than a style
attribute, since a nonce rescues the element and nothing rescues the attribute.

<Skullet.Boot.boot nonce={@csp_nonce} />
<Skullet.provider theme={%{radius: "6px"}} nonce={@csp_nonce}>
  …
</Skullet.provider>
usage has the plug, the session hop and the rest.
Where to read next
Usage covers the data sources, attributes, slots and the empty and error
states; theming the custom properties and the provider that sets them
in one place; reveals how content replaces its skeleton; and
internals how measuring works and how the engine is built.
API reference: Skullet.skeleton/1, Skullet.provider/1, Skullet.box/1,
Skullet.Boot.boot/1, Skullet.Memory. Changes are in the
changelog.


  

    Changelog

Unreleased
0.1.0 - 2026-11-10
Added
	<Skullet.skeleton> draws a skeleton of the component itself: your markup is rendered
from a sample with its text transparent, measured by the browser, and covered with bars —
one per wrapped line, one block per image or control. It takes an assign_async/3 result,
plain data, or a loading flag.
	Slots for the states around loading: skeleton for your own markup to measure (the
Suspense shape, together with error), empty_message with the empty attribute for a
result that arrived empty, and error for a failed assign. The library styles none of
them.
	remember keeps the data a skeleton last showed, in ETS on the node, so the next
skeleton under the same scope and id is drawn from the real thing instead of the sample.
Skullet.Memory.forget/1 clears one scope, Skullet.Memory.clear/0 clears all of them,
and entries expire after config :skullet, :memory_ttl_ms.
	Theming through custom properties — base and highlight colours, radius,
shimmer / group-shimmer / pulse / none, speed, hold, and how much of each line is
drawn — set per skeleton with theme={…} or once with <Skullet.provider>, which also
sets mode, animation and speed for everything inside it.
	Reveals: smart (instant for a flash, a quick crossfade for a refetch, one crossfade for
small content, a page cascade otherwise), plus together, sequence, sweep and
instant, with their timings and enter effects as custom properties.
	registerReveal/2 and attach(root, {reveal: spec}) take a reveal of your own:
order, enter, wipe, delay, duration, hold and choose.
	<Skullet.Boot.boot /> draws the skeletons already in the server's HTML before the
browser's first paint, from the same geometry, font metrics and shimmer the engine uses.
	<Skullet.box> stands in for what cannot be measured (a logo, a chart, a canvas);
skullet-block and skullet-ignore hint the measurement.
	Images that decode after the content arrives fade in instead of popping, and show after
ten seconds if they never do.
	A debug overlay outlines every reveal, and how far the content moved, with
?skullet-debug in the URL, skullet-debug on an element, or skullet-xray to see the
sample through the skeleton.
	Works under a Content Security Policy without 'unsafe-inline': themes and boxes are
<style> blocks signed with the page's nonce, and so is the boot script. Pass
nonce={…} to skeleton/1, provider/1, box/1 and Boot.boot/1.
	priv/static ships an ES module for bundlers (skullet.js), the same engine as a script
for pages without a build step (skullet.min.js, which defines window.Skullet), the
inlined pre-paint script, and a hand-written skullet.d.ts.

Compatibility
	Elixir ~> 1.18, Phoenix LiveView ~> 1.2, Phoenix.HTML ~> 4.3.
	Under a Content Security Policy, script-src and style-src need the nonce; no
'unsafe-inline' is required.



  

    Usage

The component is one tag with a sample of the data that is coming, and whatever markup
should stand in for the content while it loads.
With an async assign
def mount(%{"id" => id}, _session, socket) do
  {:ok, assign_async(socket, :user, fn -> {:ok, %{user: Accounts.get_user!(id)}} end)}
end
<Skullet.skeleton :let={user} id="profile" async={@user} sample={@sample_user}>
  <Profile.card user={user} />
</Skullet.skeleton>
While @user is loading, Profile.card is rendered from @sample_user and measured. When
the assign resolves and LiveView patches the real user in, the skeleton crossfades out.
During the dead render the skeleton is the whole page, so the layout never jumps on connect.
A background refetch keeps the content on screen: assign_async/3 leaves the previous
result in place while the new one loads, and the skeleton only returns when the assign is
reset — pass reset: true (or assign a fresh AsyncResult.loading()).
With plain data
<Skullet.skeleton :let={user} id="profile" data={@user} sample={@sample_user}>
  <Profile.card user={user} />
</Skullet.skeleton>
data that is nil means loading; anything else is loaded. Same component, same skeleton.
Attributes
	attribute	type	default	what
	id	string, required	—	DOM id for the hook; a generated one would change every render and remount the hook
	sample	any, required	—	stands in for the data to draw the skeleton
	async	%AsyncResult{}	nil	from assign_async/3
	data	any	nil	plain data; nil is loading
	loading	boolean	false	forces the skeleton, even over data
	empty	boolean	false	shows the empty_message slot in place of the content (see empty states)
	reveal	"smart" | "together" | "sequence" | "instant"	"smart"	how content replaces its skeleton (see reveals)
	theme	map	%{}	custom properties for this skeleton alone (see theming)
	label	string	"Loading"	read to screen readers while loading
	remember	any	nil	opt in to memory under this scope (see memory)

Slots: inner_block (required, receives the sample then the real value), skeleton (your
own markup to measure instead of the sample — see per-component
skeletons), error (rendered in place of the content when the
async assign failed — see errors) and empty_message (rendered in place of the
content while empty is true — see empty states).
Empty states
An empty result is neither loading nor an error: the data arrived and there is nothing in
it. empty swaps the content pane for the empty_message slot, and the reveal treats that
message as content — it measures it and eases to its height, with no skeleton of its own.
<Skullet.skeleton :let={messages} id="inbox" data={@messages} sample={@sample_messages}
  empty={@messages == []}>
  <Inbox.messages messages={messages} />
  <:empty_message>
    <p class="rounded-lg border border-dashed border-base-300 p-6 text-center text-sm">
      No messages yet.
    </p>
  </:empty_message>
</Skullet.skeleton>
It is your markup, styled none of it by the library — the same deal as the error slot.
Two rules keep it predictable:
	Content first. empty only replaces content that arrived. While the data is still
missing the skeleton shows as usual (from the sample — the result is not known to be
empty yet), and a failed assign still renders the error slot instead.
	No message, no change. Leave the slot out and the content stays: empty on its own
renders what it always did.

With an async assign, emptiness rides on the result:
empty={@messages.ok? and @messages.result == []}
Errors
The error slot is your markup, and the library styles none of it: an alert, an empty
state, a retry form, or the same card frame around all three. It replaces the content pane
when the assign failed, and the loading label goes with it.
<Skullet.skeleton :let={user} id="profile" async={@user} sample={@sample_user}>
  <Profile.card user={user} />
  <:error>
    <div class="rounded-lg border border-error/40 bg-error/10 p-4">
      <p class="text-sm">Could not load the profile.</p>
      <button phx-click="retry" class="btn btn-xs mt-2">Try again</button>
    </div>
  </:error>
</Skullet.skeleton>
Want the error inside your card — same border, same padding — rather than in place of it?
Render that frame in the slot:
<:error>
  <Profile.card user={@sample_user} class="opacity-60">
    <:footer><p class="text-sm">Could not load.</p></:footer>
  </Profile.card>
</:error>
Boxes
For what cannot be measured — a logo, a chart, a canvas — put a box in the sample in place
of the thing:
<Skullet.box width={240} height={120} radius="12px" />
It is drawn as a single block, like anything marked skullet-block.
Per-component skeletons
Some things measure badly however you mark them. Give the component a companion skeleton
and pass it to the skeleton slot — it is rendered and measured in place of the sample:
<Skullet.skeleton id="chart" async={@chart} sample={@sample}>
  <Chart.chart chart={…} />
  <:skeleton><Chart.skeleton /></:skeleton>
</Skullet.skeleton>
Chart.skeleton/1 is ordinary markup — <Skullet.box> blocks, a placeholder axis, an
outline of the chart. It is only shown while loading, and the bars are measured from it
rather than from the real chart.
This is also the Suspense shape: an async assign, a measured fallback while it loads, and
one error branch. There is no separate component for it:
<Skullet.skeleton :let={quote} id="quote" async={@quote} sample={@sample_quote}>
  <Quote.quote quote={quote} />
  <:skeleton><Quote.quote quote={@sample_quote} /></:skeleton>
  <:error>Could not load the quote.</:error>
</Skullet.skeleton>
Hints
Measuring gets most markup right. Where it does not — a logo, a chart, a canvas — say so
in the markup:
<div skullet-block>…</div>          <!-- one block, nothing inside it measured -->
<span skullet-ignore>New</span>     <!-- left out entirely -->
Memory
The first skeleton of a session is drawn from your sample. Every one after that can be
drawn from the real data instead, which makes it exact at any viewport size:
<Skullet.skeleton :let={user} id="profile" async={@user} remember={@current_user.id}>
  <Profile.card user={user} />
</Skullet.skeleton>
remember is the scope — usually the user's id — and id completes the key. Once the
skeleton has shown real data, the next loading render uses that data in place of the
sample.
It is stored server-side (ETS), not in the browser: no shapes in localStorage, nothing
left on a shared device, and it works across devices because it is data rather than pixels.
It is per node, and it expires after config :skullet, :memory_ttl_ms (30 minutes by
default). Clear a person's memory when they sign out:
Skullet.Memory.forget(current_user.id)
Images
An image that is still decoding when the content arrives would pop in. It waits at zero
opacity and fades in when it is ready; one that never arrives shows after ten seconds
rather than staying hidden. Give images a width and height (or an aspect-ratio) — that
is what reserves their space, with or without a skeleton over it.
Before the first paint
The sample is laid out from the server's HTML, but the bars are drawn by JavaScript — so
until the bundle loads and the LiveView mounts, the page shows an empty box. One component
closes that gap:
<%!-- once per page, at the end of <body>, after the markup it measures --%>
<Skullet.Boot.boot nonce={assigns[:csp_nonce]} />
It inlines a ~9KB script that measures and draws every loading skeleton synchronously,
before the browser's first paint, using the same geometry, font metrics and shimmer code
as the engine; the engine then takes those bars over.
It is a plain <script>, so a Content Security Policy needs its nonce; the next section
is the whole recipe. Without a CSP, leave the attribute off.
Content Security Policy
Skullet needs a nonce in two places, and neither of them is 'unsafe-inline':
	the boot script, which <Skullet.Boot.boot /> inlines into the page;
	the theme, which is emitted as a <style> block rather than a style attribute —
a nonce rescues <style> elements, and nothing rescues a style attribute.

Everything else is ordinary: the engine and the stylesheet are assets from your own origin,
and the bars are positioned through the CSSOM, which no policy blocks.
Make the nonce where the policy is made, keep it for the rest of the request, and hand it to
whatever emits markup:
# lib/my_app_web/plugs/csp.ex
defmodule MyAppWeb.CSP do
  @behaviour Plug
  import Plug.Conn

  @impl true
  def init(opts), do: opts

  @impl true
  def call(conn, _opts) do
    nonce = Base.url_encode64(:crypto.strong_rand_bytes(16), padding: false)

    conn
    |> assign(:csp_nonce, nonce)
    # the LiveView's own render can only read it from the session
    |> put_session(:csp_nonce, nonce)
    |> put_resp_header("content-security-policy", policy(nonce))
  end

  defp policy(nonce) do
    "default-src 'self'; " <>
      "script-src 'self' 'nonce-#{nonce}'; " <>
      "style-src 'self' 'nonce-#{nonce}'; " <>
      "img-src 'self' data:; connect-src 'self'; base-uri 'none'"
  end
end
# router.ex, in the :browser pipeline, before any LiveView mounts
plug :fetch_session
# …
plug MyAppWeb.CSP
# the LiveView
def mount(_params, session, socket) do
  {:ok, assign(socket, :csp_nonce, session["csp_nonce"])}
end
Then pass it to the four places that emit markup:
<%!-- layouts/root.html.heex --%>
<Skullet.Boot.boot nonce={@csp_nonce} />

<%!-- any inline script of your own, e.g. a theme bootstrap --%>
<script nonce={@csp_nonce}>…</script>

<%!-- the theme: a provider, a skeleton with its own theme, a box --%>
<Skullet.provider theme={%{radius: "6px"}} nonce={@csp_nonce}>
  <Skullet.skeleton id="chart" sample={@sample} theme={%{speed: "fast"}} nonce={@csp_nonce}>
    <Skullet.box width={240} height={120} nonce={@csp_nonce} />
  </Skullet.skeleton>
</Skullet.provider>
theme and mode become #the-id { --skullet-…: … } in a <style> block that carries the
nonce, and a box becomes a class plus its own rule — which is why nothing needs a style
attribute. Without a nonce, the same blocks are emitted unsigned and a strict policy drops
them, so the theme silently falls back to the defaults.
Two things that surprise people:
	The nonce has to reach the LiveView, not just the request. The root layout is rendered
twice — once for the HTML the request sends, once by the LiveView after it connects — and
the second render has only socket assigns. The session is the one place both see, which is
why the plug writes it there. Skip that and the attribute is simply dropped on the second
render; the script has already run by then, but the markup no longer tells the truth.
	A style attribute cannot be rescued by a nonce. That is why the theme is a rule and
a box is a class: per-instance styling belongs in a <style> block with the nonce on it.
A chart of your own with per-bar heights wants the same treatment.

Debugging
Add ?skullet-debug to the URL to outline every skeleton: blue while it loads, then green
if the content arrived where the skeleton was, red with the distance in the title if it
moved. skullet-debug on any one element does the same for that subtree, and
skullet-xray on an ancestor shows the sample through the skeleton.
Plain pages
The engine does not need LiveView. Given the markup the component renders, attach(root)
starts the engine on that element and setDebug(on) turns the outline on for the page:
import { attach, setDebug } from "../../deps/skullet/priv/static/skullet.js"

attach(document.querySelector(".skullet"))
attach returns the engine, so a page that swaps content itself drives it the way the
LiveView hook does: beforeUpdate(), then update() after the new markup is in, and
destroy() when the element goes. It takes the reveal as an option —
attach(root, { reveal: spec }) — which wins over the element's reveal attribute; see
reveals.
The markup is the component's: a .skullet root with data-skullet-state (loading or
loaded), a [data-skullet-overlay] for the bars, and a [data-skullet-content] around
the content. Loading it without a bundler is in
installation.


  

    Theming

Everything is a CSS custom property, so one skeleton can differ from the page:
	variable	default	what
	--skullet-base	rgb(128 128 128 / 0.2) in light, rgb(255 255 255 / 0.09) in dark	the bars
	--skullet-highlight	rgb(255 255 255 / 0.75) in light, rgb(255 255 255 / 0.16) in dark	the shimmer's band
	--skullet-radius	0.25em	how round each bar is
	--skullet-hold	150ms	how long a skeleton waits before showing, so fast data never shows one
	--skullet-fade	200ms	the crossfade at the reveal
	--skullet-resize	280ms	the height ease when the real content is a different size
	--skullet-cascade	320ms	how long a sequence — or smart's cascade — takes from first piece to last
	--skullet-delay	0ms	a pause before the reveal starts
	--skullet-secondary-delay	60ms	how long small text trails the heading it sits under
	--skullet-enter-filter	none	where pieces come from: e.g. blur(6px)
	--skullet-enter-scale	1	where pieces come from: e.g. 0.98
	--skullet-animation	shimmer	shimmer, group-shimmer, pulse or none
	--skullet-speed	slow	slow or fast
	--skullet-text-top	ascender	ascender, cap-height or x-height — where each line's bar starts
	--skullet-text-bottom	descender	baseline or descender — where it ends

<Skullet.skeleton id="profile" sample={@sample_user} theme={%{speed: "fast", radius: "8px"}}>
  …
</Skullet.skeleton>
Every row above is also a theme key — the name without the prefix, so
theme={%{hold: "300ms", delay: "120ms", enter_filter: "blur(6px)"}} sets those three for
this skeleton alone, and <Skullet.provider theme={…}> sets them for everything inside.
A theme becomes a <style> block for that element's id rather than a style attribute, so
it survives a Content Security Policy: pass nonce={@csp_nonce} along with it — see
usage.
Colours follow the page's color-scheme, so a light page on a dark desktop keeps light
bars. Under prefers-reduced-motion bars hold still and every reveal is instant.
One place for the look
Everything inside a provider inherits its look, so you set it once:
<Skullet.provider mode="dark" animation="group-shimmer" speed="fast" theme={%{radius: "6px"}}>
  <.page />
</Skullet.provider>
theme, animation and speed become the custom properties the skeletons inside inherit;
a skeleton's own theme still wins.
Mode
mode sets color-scheme on the wrapper, and that is the palette the bars are drawn from
— not the page's. It is how one subtree asks for the other scheme: a dark panel on a light
page wants dark bars, so it wraps them in <Skullet.provider mode="dark">. Leave it unset
and the bars follow whatever color-scheme the page sets, which is what a theme toggle
does.
Both palettes are low-alpha fills meant for their own background — light bars on a light
page are rgb(128 128 128 / 0.2), dark ones are rgb(255 255 255 / 0.09). Forcing the
wrong one onto a surface makes the bars nearly invisible, so match mode to what is behind
the skeleton.
Animation
shimmer gives every bar its own band, all in one phase; group-shimmer sweeps a single
band across the whole skeleton, which reads better when the bars are close together. Both
follow the same rule as upstream: the band is capped at 320px, bands are 2.5 band-widths
apart on a 110° slant, and the loop is timed to a 1280px reference width so the pace is the
same on any screen. pulse fades the bars in and out, and none holds them still.


  

    Reveals

A reveal is the moment content replaces its skeleton. reveal on the skeleton (or on a
provider, or a spec handed to attach/2) says how it looks. The timings are custom
properties — see theming.
Modes
together is the crossfade without the wait. sequence takes the bars out one after
another, top to bottom. sweep wipes the skeleton away over the content, which is already
in place. instant shows and removes the skeleton with no transition.
smart (the default) decides at the moment the content lands, from how the page is being
used and what arrived:
	instant if the skeleton was up for less than --skullet-hold (150 ms), or somebody
scrolled, touched or typed in the last 400 ms — a skeleton then is a flicker, not a cue;
	a quick crossfade (120 ms) when a second cycle refetches something whose shape is
already known;
	one crossfade over --skullet-fade (200 ms) for a small reveal — under 72px tall, or
three pieces or fewer;
	a cascade down the page for anything bigger: rows arrive whole, in page order, on
screen only, main text first and small text --skullet-secondary-delay behind its
heading, spread over --skullet-cascade (320 ms), with reveals landing together sharing
one order.

Every piece can start from a filter or a scale (--skullet-enter-filter,
--skullet-enter-scale), and --skullet-delay holds the whole reveal back a beat.
Either way it eases to the content's real height over --skullet-resize (280 ms) if the
sample guessed it wrong.
A hold that is not shorter than how long the data actually takes leaves nothing to see —
no skeleton, and no reveal to animate. That is the same threshold smart reads, so raising
--skullet-hold past your latency turns every reveal instant.
Bring your own reveal
smart, together, sequence, sweep and instant are just specs; register one and ask
for it by name:
import { registerReveal } from "../../deps/skullet/priv/static/skullet.js"

registerReveal("wipe-down", {
  duration: 400,
  wipe: {
    mask: progress => `linear-gradient(#000 ${progress * 100}%, transparent)`
  }
})
<Skullet.skeleton id="profile" async={@user} sample={@sample} reveal="wipe-down">
A spec can say more than a name can:
	field	what it does
	order	"together", or (piece, settings) => ms — piece carries its rect, its unit (the row or card it belongs to), whether it is secondary (smaller text), the reveal box and how late it landed; settings carries cascade and secondaryDelay
	enter	a Keyframe each piece starts from, on top of the fade: { filter: "blur(6px)", transform: "scale(0.98)" }
	wipe	{ mask(progress, pane) → string, out? }: your own front, drawn each frame as the pane's mask-image; out masks the skeleton too, otherwise it crossfades
	delay, duration, hold	ms; duration: 0 is instant, hold replaces --skullet-hold
	choose	(context) => spec, called as the content lands with waited, input, refetch, hold, height and pieces — what it returns wins

On a plain page you can skip the registry and hand the spec straight to the engine:
attach(root, { reveal: spec }). A wipe bigger than a screen and a half falls back to a
crossfade, and everything is instant under prefers-reduced-motion.
The types are on skullet.d.ts in the package: RevealSpec, RevealContext, Piece,
Wipe and the rest.


  

    Internals

How it works
Skullet does not guess at sizes: it lets the browser lay out the real content, then reads
the result.
	Layout by the browser. Your content renders in place from the closest data there is
— the sample, or the data a previous cycle remembered — with its text transparent and its
media hidden. Every size and line break is the browser's own.
	Lines from the DOM. Each text node is measured with Range.getClientRects(), which
returns one box per line it wraps to. Images, controls and painted boxes such as buttons
and chips are measured whole.
	Heights from the font. A line box is taller than its letters, so each bar is trimmed
to the font's own metrics, read once per font with canvas measureText: ascender to
descender by default.
	Drawn on top. The bars are absolutely positioned over the unseen content, in a shadow
root the page's CSS cannot reach. Every bar shares one shimmer, timed by the document
clock and its place on the page.
	Kept current. A ResizeObserver, a MutationObserver, image loads and font loads
trigger a re-measure.

First paint
The server renders the sample, so the layout is right from the first byte, but the bars are
drawn by JavaScript: between the first paint and the bundle running, a loading skeleton is
an empty box. <Skullet.Boot.boot/1 /> closes that gap by inlining priv/static/skullet.pre.js
— a self-contained bundle of the same measuring, metrics and shimmer code — as a
synchronous <script>. It paints before first paint, and the engine takes the bars over
when it starts.
Place it once per page, at the end of <body>; see usage
for the component and the CSP section for its nonce.
Working on the engine
The package needs no Node: the compiled engine is committed in priv/static. Changing it
needs pnpm and Node, from the repository root:
pnpm install --allow-build=esbuild   # esbuild's postinstall is declined by default
pnpm run check   # tsc (type check), oxlint, oxfmt --check
pnpm build       # assets/js/*.ts → priv/static/skullet{.js,.min.js}, then skullet.pre.js
pnpm test        # builds, then drives Playwright against assets/test/fixtures

oxfmt reads assets/.oxfmtrc.json.
priv/static holds bundles, not a file per module: one ESM bundle for bundlers, one
minified script for a <script> tag, both maps-free except the script build, plus the
hand-written skullet.d.ts. pnpm verify rebuilds and fails if the committed files would
change.
Before finishing a change
mix ci runs the whole quality gate — compile --warnings-as-errors, format --check-formatted, coveralls (the test suite, with line coverage and a 95% floor),
credo --strict, dialyzer, spec_lint --warnings-as-errors, ex_dna --max-clones 0 and
reach.check --arch --smells — set up by
VibeKit. mix coveralls.html writes the
per-line report to cover/.
The demo app
example/ is a Phoenix LiveView app using the component on a real assign_async, with a
button that pins the loading state:
cd example && mix deps.get && mix assets.setup && mix phx.server

It runs at http://localhost:4000; the deployed copy is
https://skullet-demo.fly.dev/. example/README.md covers what each card shows and how it
is deployed.

Draws a skeleton of what is about to load.
While data is missing, your own component is rendered from a sample with its text
transparent, the browser lays it out for real, and rounded bars are drawn over it — one
per wrapped line, one block per image or control. Nothing is guessed, so nothing moves
when the content arrives.
The most common shape, one assign_async/3 and a sample:
<Skullet.skeleton :let={user} id="profile" async={@user} sample={@sample_user}>
  <Profile.card user={user} />
</Skullet.skeleton>
Wiring, in the app's assets/js/app.js and assets/css/app.css:
import { SkulletHook } from "../../deps/skullet/priv/static/skullet.js"
new LiveSocket("/live", Socket, { hooks: { Skullet: SkulletHook } })

@import "../../deps/skullet/priv/static/skullet.css";
The CSS is not optional: it keeps the sample invisible before the engine runs.
Under a Content Security Policy the boot script and the theme's <style> block need the
page's nonce: nonce={@csp_nonce} on skeleton/1, provider/1 and box/1; see the
CSP section.
The detail lives in the guides:
	Usage — async assigns and plain data, attributes and slots, empty and
error states, memory, images, plain pages without LiveView.
	Theming — every custom property, the theme map, the provider.
	Reveals — how smart decides, the built-in modes, specs of your own.
	Internals — how measuring works, first paint, the engine's build.

Skullet.Boot.boot/1 covers the gap before the bundle loads, and Skullet.Memory
backs remember.

    Functions
  


    
      
        box(assigns)

      


        A placeholder block for what cannot be measured — a logo, a chart, a canvas.



    


    
      
        provider(assigns)

      


        Sets the skeleton's look for everything inside — one place instead of every skeleton.



    


    
      
        skeleton(assigns)

      


        


    





      


      
        Functions


        


  
    
      
    
    
      box(assigns)



        
          
        

    

  


  

      

          @spec box(map()) :: Phoenix.LiveView.Rendered.t()


      


A placeholder block for what cannot be measured — a logo, a chart, a canvas.
Put it inside the skeleton's sample in place of the thing, sized like the thing:
<Skullet.skeleton :let={report} id="report" async={@report} sample={@sample}>
  <Skullet.box width={240} height={120} />
  <p>{report.title}</p>
</Skullet.skeleton>
Attributes
	width (:any) - any CSS length, or a number of pixels. Defaults to "60%".
	height (:any) - any CSS length, or a number of pixels. Defaults to "1em".
	radius (:any) - defaults to --skullet-radius. Defaults to nil.
	nonce (:string) - the CSP nonce for the <style> block this emits. Defaults to nil.


  



  
    
      
    
    
      provider(assigns)



        
          
        

    

  


  

Sets the skeleton's look for everything inside — one place instead of every skeleton.
<Skullet.provider mode="dark" animation="group-shimmer" speed="fast">
  …
</Skullet.provider>
mode sets color-scheme on the wrapper, which is what the bars' colours follow, so
"dark" gives dark-page bars even where the page itself is light. theme, animation
and speed become the custom properties the skeletons inside inherit.
Attributes
	id (:string) - DOM id for the wrapper. Defaults to nil.
	nonce (:string) - the CSP nonce for the <style> block this emits. Defaults to nil.
	mode (:string) - Defaults to nil.Must be one of nil, "light", "dark", or "system".
	animation (:string) - Defaults to nil.Must be one of nil, "shimmer", "group-shimmer", "pulse", or "none".
	speed (:string) - Defaults to nil.Must be one of nil, "slow", or "fast".
	theme (:map) - custom properties for everything inside. Defaults to %{}.
	Global attributes are accepted.

Slots
	inner_block (required)


  



  
    
      
    
    
      skeleton(assigns)



        
          
        

    

  


  

      

          @spec skeleton(map()) :: Phoenix.LiveView.Rendered.t()


      


Attributes
	id (:string) (required) - DOM id for the hook; also the future shape key.
	async (:any) - a %Phoenix.LiveView.AsyncResult{}. Defaults to nil.
	data (:any) - plain data; nil means loading, anything else is loaded. Defaults to nil.
	sample (:any) (required) - stands in for the data to draw the skeleton.
	loading (:boolean) - forces the skeleton, even over data. Defaults to false.
	empty (:boolean) - shows the empty_message slot in place of the content. Defaults to false.
	reveal (:string) - smart, together, sequence, sweep, instant, or a name registered with registerReveal/2 in JS. Defaults to "smart".
	theme (:map) - custom properties to override on this skeleton. Defaults to %{}.
	nonce (:string) - the CSP nonce for the <style> block this emits when theme is set. Defaults to nil.
	label (:string) - read to screen readers while loading. Defaults to "Loading".
	remember (:any) - opts in to remembering the data this skeleton last showed, under this scope. Defaults to nil.

Slots
	error - rendered in place of the content when the async assign failed. It is your markup —
the library styles none of it — so an alert, an empty state, or your own card frame
all work here.

	skeleton - your own markup to measure instead of the sample — for a logo, a chart, a canvas.
It is rendered while loading in place of the inner block.

	empty_message - rendered in place of the content while empty is true — the content itself when left
out. It is your markup: the library styles none of it, so a dashed box, an illustration
or a card frame all work here.

	inner_block (required) - receives the sample, then the real value.



  


        

      


  

    
Skullet.Boot 
    



      
Draws the skeletons already in the server's HTML before the browser's first paint.
Without it, the sample is laid out and hidden from the first paint, but the bars only
appear once the engine's bundle has loaded and the LiveView has mounted — a blank box
for those few hundred milliseconds. The script measures and draws synchronously, using
the same geometry, metrics and shimmer code the engine uses.
Render it once per page, after the markup it measures:
<Skullet.Boot.boot nonce={@nonce} />
It is about 9KB of JavaScript inlined into the page, so it is your call to place it. Being
inline, a Content Security Policy needs its nonce — usage
has a plug that makes one and carries it into the LiveView.

    Functions
  


    
      
        boot(assigns)

      boot(assigns)



        
          
        

    

  


  

      

          @spec boot(map()) :: Phoenix.LiveView.Rendered.t()


      


Attributes
	nonce (:string) - the CSP nonce for the inline script. Defaults to nil.


  


        

      


  

    
Skullet.Memory 
    



      
Remembers the data a skeleton last showed, so its next skeleton is drawn from that
instead of from a hand-written sample.
The upstream JavaScript library remembers shapes in localStorage; a Phoenix app can
do better and remember the data, then render it: the skeleton is measured from the
real component and is exact at any viewport size, on any device.
Opt in per skeleton:
<Skullet.skeleton :let={user} id="profile" async={@user} remember={@current_user.id}>
  …
</Skullet.skeleton>
remember is a scope — usually the user's id — and the skeleton's id completes the
key. While loading, a remembered value is used as the sample; once loaded, the real
value replaces it.
The store is this node's memory only: it is not shared between nodes, it expires after
config :skullet, :memory_ttl_ms (30 minutes by default), and it must be cleared when
somebody signs out — forget/1 with their scope, from wherever that happens.

      


      
        Summary


  
    Types
  


    
      
        key()

      


        The skeleton's id attribute, which completes the key with the scope.



    


    
      
        option()

      


        How far back get/3 looks; :ttl_ms may be negative, which expires everything.



    


    
      
        scope()

      


        The scope a skeleton remembers under: usually the current user's id, but any term works
— a tenant, an account, :global.



    


    
      
        value()

      


        The data the skeleton last showed: whatever your component was passed.



    





  
    Functions
  


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    


    
      
        clear()

      


        Forgets everything, for every scope.



    


    
      
        forget(scope)

      


        Forgets everything remembered under scope, as on sign-out.



    


    
      
        get(scope, id, opts \\ [])

      


        The value remembered for scope and id, or nil.



    


    
      
        put(scope, id, value)

      


        Remembers value for scope and id.



    


    
      
        start_link(opts)

          @type key() :: String.t()


      


The skeleton's id attribute, which completes the key with the scope.

  



  
    
      
    
    
      option()



        
          
        

    

  


  

      

          @type option() :: {:ttl_ms, integer()}


      


How far back get/3 looks; :ttl_ms may be negative, which expires everything.

  



  
    
      
    
    
      scope()



        
          
        

    

  


  

      

          @type scope() :: term()


      


The scope a skeleton remembers under: usually the current user's id, but any term works
— a tenant, an account, :global.

  



  
    
      
    
    
      value()



        
          
        

    

  


  

      

          @type value() :: term()


      


The data the skeleton last showed: whatever your component was passed.

  


        

      

      
        Functions


        


  
    
      
    
    
      child_spec(init_arg)



        
          
        

    

  


  

Returns a specification to start this module under a supervisor.
See Supervisor.

  



  
    
      
    
    
      clear()



        
          
        

    

  


  

      

          @spec clear() :: :ok


      


Forgets everything, for every scope.

  



  
    
      
    
    
      forget(scope)



        
          
        

    

  


  

      

          @spec forget(scope()) :: :ok


      


Forgets everything remembered under scope, as on sign-out.

  



    

  
    
      
    
    
      get(scope, id, opts \\ [])



        
          
        

    

  


  

      

          @spec get(scope(), key(), [option()]) :: value() | nil


      


The value remembered for scope and id, or nil.
Options
	:ttl_ms — how old a value may be; defaults to config :skullet, :memory_ttl_ms


  



  
    
      
    
    
      put(scope, id, value)



        
          
        

    

  


  

      

          @spec put(scope(), key(), value()) :: :ok


      


Remembers value for scope and id.

  



  
    
      
    
    
      start_link(opts)



        
          
        

    

  


  

      

          @spec start_link(keyword()) :: GenServer.on_start()


      



  


        

      


  OEBPS/dist/epub-4WIP524F.js
(()=>{var s=document.querySelector.bind(document),o=document.querySelectorAll.bind(document);function r(e){document.readyState!=="loading"?e():document.addEventListener("DOMContentLoaded",e)}var l="hll";window.addEventListener("exdoc:loaded",t);function t(){o("[data-group-id]").forEach(e=>{e.addEventListener("mouseenter",i),e.addEventListener("mouseleave",i)})}function i(e){let n=e.currentTarget,a=e.type==="mouseenter",c=n.getAttribute("data-group-id");n.parentElement.querySelectorAll(`[data-group-id="${c}"]`).forEach(u=>{u.classList.toggle(l,a)})}r(()=>{t()});})();




